Facebook
Google
GitHub
LinkedinThe Bipolar Transistor SPICE Model
The bipolar transistor is represented by 42 parameters in SPICE! While the number may look a bit daunting, it's actually quite straightforward once you're familiar with the SPICE diode model.
Bipolar Spice Model Parameters
The SPICE parameters for the bipolar transistor are placed into five groups:
- Base-emitter diode.
- Current gain.
- Reverse current gain.
- Base-collector diode.
- Noise.
Let’s take a detailed look at each of these five groups.
Base-Emitter Diode
Here we have the plain diode SPICE parameters as discussed in the diode model, but renamed. The abbreviations in parentheses refer to the ordinary diode parameters: IS (IS), NF (N), ISE (ISR), NE (NR), RE (RS), EG, XTI, CJE (CJO), VJE (VJ), MJE (M), FC.
The series resistance of the diode is divided into two parts:
- RE: at the emitter end, with the emitter current flowing through it.
- RB: at the base-contact end.
The latter starts at RB at low current and drops gradually to the value RBM at a current specified by IRB. At low current, this reflects the use of the entire emitter. At high current, as discussed in the performance limitations of bipolar transistors, it reflects only the emitter edge facing the base contact.
Current Gain
The main parameters here are BF (the forward beta, or hFE) and its temperature coefficient XTB. Without any additional parameters, the current gain would be the same at any collector voltage or current.
The Early effect is represented by VAF (the Early voltage). The drop-off at high current is produced by IKF (the current at which hFE starts to drop) and NK (the steepness of the drop). ISE and NE of the base-emitter diode are responsible for the drop in hFE at the low-current end; simply shunting a small amount of base current to the emitter.
Reverse Current Gain
You may be convinced that you will never operate a transistor with the collector and emitter interchanged, but just in case, the parameters BR, NR, VAR, IKR, and TR are provided.
Base-Collector Diode
Here again, we have the basic diode SPICE parameters, again renamed: ISC (IS), NC (N), RC (RS), XTF (XTI), CJC (CJO), VJC (VJ), MJC (M) and TF (TT).
The last one, TF, is the transit time (now through the base to the collector) which accounts for any delay that can't represented by capacitance alone. It is embellished by:
- ITF: which makes TF dependent on current.
- VTF: showing the dependence of TF on the base-collector voltage.
- PTF: an excess phase at a frequency 1/(2πTF).
Noise
As in a simple diode, additional low-frequency (flicker) noise is represented by the parameters KF and AF, but here they work on the collector current.
Basic Model Limitations
The SPICE model for an integrated bipolar transistor can have either three or four terminals. The fourth terminal (of an NPN transistor) is the substrate. Between the substrate and the collector, there is a diode represented by the five parameters ISS, NS, CJS, VJS, and MJS. This is a major flaw in SPICE, for a mere diode here is inadequate. When the transistor saturates, a substantial portion of the total current flows to the substrate, which this model simply ignores.
Using a Subcircuit To Improve the Bipolar Model
Fortunately, SPICE also contains a solution to this problem. To represent an NPN transistor correctly, you need to add a second transistor, as illustrated in Figure 3-13. SPICE lets you combine the two (or any number of) devices in a subcircuit.
Figure 3-13. Equivalent circuit for an integrated NPN transistor.
When the NPN transistor, N1, saturates (i.e., the collector drops below the base potential), the PNP transistor P1 becomes active and draws base current to the substrate. This is what happens in real life: there is a stray PNP transistor formed by the base (P), the collector (i.e. the epitaxial layer, N), and the substrate (P).
Rather than put the stray capacitance and leakage current between the collector and substrate into the PNP transistor (which is somewhat cumbersome), a separate diode DCS is inserted, as shown in Figure 3-13.
The figure also shows DZ, a Zener diode, which corrects another flaw of SPICE: there are no breakdown voltages in the bipolar transistor model. We need this effect for the base-emitter diode because it is sometimes used as a Zener diode. If you also want to have a collector-emitter breakdown, place an additional Zener diode between collector (cathode) and base.
The model for this subcircuit appears as follows:
.SUBCKT NPN1 1 2 3 4
Q1 1 2 3 N1
Q2 4 1 2 P1
D1 2 3 DZ
D2 4 1 DCS
.ENDS
The first line begins with a .SUBCKT (all models start with a dot) and then lists the name of the subcircuit, NPN1 in our example, and the order of connections (which will be followed in the netlist). The next four lines list the device types, their connections, and the name of each device model. The last line signifies the end of the subcircuit listing.
As an aside, SPICE lets you define global nodes. This is especially convenient for the substrate and avoids cluttering up the schematic with unnecessary lines. This feature is used throughout this book for bipolar devices. However, you will have to remember to place the contact to the substrate (SUB) at the appropriate point (almost always the most negative supply).
SPICE now needs a model for each of the devices used. For example, here are the models for a 20 V process:
.MODEL N1 NPN IS=3.8E-16 BF=220 BR=0.7
+ ISE=1.8E-16 IKF=2.5E-2 NK=0.75 IKR=3E-2 NE=1.4 VAF=60
+ VAR=7 RC=63.4 RB=300 RE=19.7 XTB=1.17 XTI=5.4
+ TF=1.5E-10 TR=6E-9 XTF=0.3 VTF=6 ITF=5E-5 CJE=0.21E-12
+ MJE=0.33 VJE=0.7 ISC=5E-12 KF=2E-13 AF=1.4
.MODEL P1 PNP IS=1E-15 BF=100 CJE=0.175E-12 XTI=5.4 MJE=0.38 VJE=0.6
.MODEL DZ D IS=1E-18 RS=250 BV=5.9 IBV=10UA TBV1=1.8E-4
.MODEL DCS D IS=1E-17 RS=10 ISR=5E-12 CJO=0.85E-12 M=0.42 VJ=0.6
Note that the model for DZ has no capacitance; this is already present in the base-emitter diode of N1.
